I'm not sure all that you've tried, but typically the problems associated with recording experiment data to a global table arises from the fact that each replication of an experiment is sent off to one of multiple processing cores on your computer.
I have had success recording information written to a global table during a model run out to an external csv file at the end of each replication of the experiment. In my example, the global table is named "Trace".
I put the following code in the "Start of Experiment" field of the Experiment Control Window's Advanced tab:
/**Save off a reference to the model directory*/
sets(assertsubnode(node("Tools", model), "ModelDir", DATATYPE_STRING), modeldir());
and I put the following code in the "End of Replication" field:
//////////////////////////////////// CODE HEADER //////////////////////////////////////////////////////////////////////
double replication = parval(1);
double scenario = parval(2);
treenode childexpfolder = parnode(3);
///////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
{ //************* PickOption Start *************\\
/**Write the current rep's Trace table data to a csv file*/
// only do this on the child process
if (!objectexists(childexpfolder))
{
/**\n\nFile name: */
string modelDir = gets(node("Tools/ModelDir", model));
string filename = /**/concat(modelDir, "S", numtostring(scenario), "R", numtostring(replication), "_PatientTrace.csv")/**/;
//delimeter character used to separate data into columns
int comma = 44;
int tab = 9;
int semicolon = 59;
int CR = 13;
/**\nData delimeter: */
int delimeter = /**/comma/**list:comma~tab~semicolon*/;
//create csv file and write column headers
int fileHandle = fileopen(filename, "w");
// Add scenario and replication column headers first
fpt("Scenario, Replication, ");
int rows = nrows(Trace);
int cols = ncols(Trace);
for(int column=1; column<=cols; column++)
{
fpt(gettableheader(Trace,2,column));
if(column < cols)
{
fpc(delimeter);
fpt(" ");
}
else
fpc(CR);
}
// Loop through the Trace table and append data to the file one row at a time
for(int row = 1; row <= rows; row++)
{
// Record the current scenario and replication as the first two columns of data
fpd(scenario);
fpc(delimeter);
fpt(" ");
fpd(replication);
fpc(delimeter);
fpt(" ");
for(int col = 1; col <= cols-1; col++)
{
if(col == TRACE_COL_PatientID
|| col == TRACE_COL_SlotIsAvailable
|| col == TRACE_COL_InitialDose
|| col == TRACE_COL_ScreenFail
|| col == TRACE_COL_ActualDose)
fpd(gettablenum(Trace, row, col));
else if(col == TRACE_COL_FinalDisposition)
fpt(gettablestr(Trace, row, col));
else
fpf(gettablenum(Trace, row, col));
fpc(delimeter);
fpt(" ");
}
fpt(gettablestr(Trace, row, cols));
fpc(CR);
}
fileclose();
} // if (!objectexists(childexpfolder))
/** \n\n*/
} //******* PickOption End *******\\
