question

My approach would be to build upon the "Set Label By Percentage" option. With labels the object can keep track of whether a label value is allowed to be assigned or not (as a combination of the min. intervals and the number of items since that label was last assigned). If the value can not be assigned right now, it is written to an array of pending values and a new random value is generated until the label can be assigned. This is done to not alter the quantity of how often a value is assigned overall, but only delay assigning it. Each time the trigger fires, the code first checks if any of the pending values can now be assigned. If not, or there aren't any, it goes back to generating random values.

In the example model that is linked below I use a bundle label on the source to keep track of when the values can be assigned. The "AllowedIn" column is set to the "MinInterval" value when the value is used and decremented each time a new item is generated. If the number in that column is 0, the value is allowed to be assigned.

The "Value" column is indexed (Rightclick on the column header to see the option), for fast lookup of the correct row in the code.

As mentioned above, the default "Set Label By Percentage" option forms the basis of the code with the rest added around it.

int stream = getstream(current);
// Decrement bundle "AllowedIn" column
treenode bundleLabel = current.labels["MinIntervals"];
int numRows = getbundlenrentries(bundleLabel);
for(int i = 0; i < numRows; i++)
{
    setbundlevalue(bundleLabel, i, "AllowedIn", Math.max(0, getbundlevalue(bundleLabel, i, "AllowedIn")-1));
}

// Get next number
// Check value queue first
for(int j = 1; j <= current.ValueQueue.length; j++)
{
    Variant value = current.ValueQueue[j];
    // Check if number is allowed
    int bundleRow = getbundleindexentries(bundleLabel, "Value", value)[1];
    if(getbundlevalue(bundleLabel, bundleRow, "AllowedIn") == 0)
    {
        // If so, set "AllowedIn" column, assign label, remove from array and terminate
        setbundlevalue(bundleLabel, bundleRow, "AllowedIn", getbundlevalue(bundleLabel, bundleRow, "MinInterval"));
        item.labels.assert("Type").value = value;
        current.ValueQueue.shift();
        return 0;
    }
}
while(true)
{
    double randomnum = uniform(0.0, 100.0, stream);
    string labelname = "Type";
    Object involved = item;
    Variant value;
    double total = 0.0;
    int foundmatch = 0;

    total += 50;
    if (!foundmatch && randomnum <= total) {
        value = "AMT_G";
        foundmatch = 1;
    }
    total += 21;
    if (!foundmatch && randomnum <= total) {
        value = "AMT_RET";
        foundmatch = 1;
    }
    total += 7;
    if (!foundmatch && randomnum <= total) {
        value = "AMT_EXT_ULC";
        foundmatch = 1;
    }
    total += 2;
    if (!foundmatch && randomnum <= total) {
        value = "AMT_PIGG";
        foundmatch = 1;
    }
    total += 2;
    if (!foundmatch && randomnum <= total) {
        value = "AMT_PS";
        foundmatch = 1;
    }
    total += 1;
    if (!foundmatch && randomnum <= total) {
        value = "AMT_HYB";
        foundmatch = 1;
    }
    total += 8;
    if (!foundmatch && randomnum <= total) {
        value = "AMT_DUAL";
        foundmatch = 1;
    }
    total += 2;
    if (!foundmatch && randomnum <= total) {
        value = "PIE";
        foundmatch = 1;
    }
    total += 7;
    if (!foundmatch && randomnum <= total) {
        value = "PIE_RET";
        foundmatch = 1;
    }

    // Check if number is allowed
    int bundleRow = getbundleindexentries(bundleLabel, "Value", value)[1];
    if(getbundlevalue(bundleLabel, bundleRow, "AllowedIn") == 0)
    {
        // If so, set "AllowedIn" column, assign label and terminate
        setbundlevalue(bundleLabel, bundleRow, "AllowedIn", getbundlevalue(bundleLabel, bundleRow, "MinInterval"));
        involved.labels.assert(labelname).value = value;
        return 0;
    }
    else
    {
        // If not push to ValueQueue
        current.ValueQueue.push(value);
    }
}

Download model (google drive)