question

The only way to do this, that I know of, is to adjust the tree of the source.

I wrote a user command that allows copying (parts of) a global table into the source schedule or sequence. It has five parameters. (Code below or in the attached model)

- The first is a reference to the source object for which you want to adjust the table.
- The second is the global from which you would like to copy the entries.
- The third controls whether the changes are applied to the "schedule" or the "sequence" table, by given one of the two names.
- The fourth and fifth parameters are optional and let you specify the start and end row inbetween which you want to copy over the entries. If you don't pass these in, the entire table will be copied over, deleting any leftover rows, if there were more rows in the source table than the global one.

An example (also in the script window of the model) would be:

UpdateSchedule(Model.find("Source1"), Table("GlobalTable1"), "sequence", 1, 3);

This would adjust the first three rows of the arrival sequence of Source1 to be equal to the first three rows of GlobalTable1.

You can use this command in any reset trigger and loop through all sources you want to copy the changes to.

arrivals_fm.fsm

User command code:

/**Custom Code*/
Object Source = param(1);
Table Data = param(2);
string Mode = param(3);
int StartRow = param(4);
int EndRow = param(5);

int deleteFurtherEntries = 0;
if(!StartRow)
{
    StartRow = 1;
}
if(EndRow > Data.numRows)
{
    EndRow = Data.numRows;
}
if(!EndRow)
{
    EndRow = Data.numRows;
    deleteFurtherEntries = 1;
}

treenode schedule = Source.find(">variables/" + Mode);
treenode curRowNode;
treenode curColNode;

for(int row = StartRow; row <= EndRow; row++)
{
    if(schedule.subnodes.length < row)
    {
        schedule.subnodes.add();
    }
    curRowNode = schedule.subnodes[row];
    curRowNode.name = Data.getRowHeader(row).as(string);

    for(int col = 1; col <= Data.numCols; col++)
    {
    if(curRowNode.subnodes.length < col)
    {
        curRowNode.subnodes.add();
    }
    curColNode = curRowNode.subnodes[col];
    curColNode.name = Data.getColHeader(col).as(string);
    curColNode.value = Data[row][col];
    }
}

if(deleteFurtherEntries)
{
    while(schedule.subnodes.length > EndRow)
    {
        schedule.subnodes[schedule.subnodes.length].destroy();
    }
}

Note: Alternatively, you could use a process flow to create the items and reference the global table directly in the "Create Objects" activity.