question

It looks like there's a bug in the exporttable command in 16.1.0 (and 16.0.2), where it's using the number of columns as the number of rows in the table.

There are a couple possible workarounds. First, you could change your global table to use bundle data. Then exporttable works properly. The downside is that you can't have named rows for bundles.

If bundle data is not an option, you could use exportdataset. The downside there is that it doesn't export row or column headers.

A poor solution (but possibly adequate for your needs) would be to add two extra columns, so that your table is square.

Finally, you could use a script like this one (for non-bundle tables):

// options of the command
string fileName = concat(modeldir(), "sample.csv");
treenode table = reftable("GlobalTable1");
int printRowHeaders = 1;
int printColHeaders = 0;

// additional options
string itemSep = ",";
string lineSep = "\n";

// precision defined by the model settings
int precision = get(node("MAIN:/1/8/1/6"));

// logic for the command
int rows = content(table);
int cols = content(first(table));

int success = fileopen(fileName, "w");
if (!success)
	return 0;

if (printRowHeaders) {
	for (int j = printColHeaders ? 0 : 1; j <= cols; j++) {
		if (j == 0 ) {
			fpt(itemSep);
		} else {
			string colHeader = getname(rank(first(table), j));
			fpt(colHeader);
			fpt(itemSep);
		}
	}
	fpt(lineSep);
}

for (int i = 1; i <= rows; i++) {
	treenode rowNode = rank(table, i);
	for (int j = printColHeaders ? 0 : 1; j <= cols; j++) {
		if (j == 0 ) {
			fpt(getname(rowNode));
			fpt(itemSep);
		} else {
			treenode curCell = rank(rowNode, j);
			int datatype = getdatatype(curCell);
			switch (datatype) {
				case DATATYPE_STRING: 
					fpt(gets(curCell)); 
					break;
				case DATATYPE_NUMBER: 
					fpt(numtostring(get(curCell), 0, precision));
					break;
			}
			fpt(itemSep);
		}
	}
	fpt(lineSep);
}

fileclose();